mac {
    QMAKE_INFO_PLIST = $$PWD/src/Info.plist
    ICON = $$PWD/src/data/icons/exeicons/qupzilla.icns

    bundle_target.files += $$PWD/bin/locale
    bundle_target.files += $$PWD/bin/themes
    bundle_target.path = Contents/Resources

    QMAKE_BUNDLE_DATA += bundle_target
}

!mac:unix {
    d_prefix = $$(QUPZILLA_PREFIX)
    binary_folder = /usr/bin
    data_folder = /usr/share/qupzilla
    launcher_folder = /usr/share/applications
    icon_folder = /usr/share/pixmaps
    hicolor_folder = /usr/share/icons/hicolor

    !equals(d_prefix, "") {
        binary_folder = "$$d_prefix"bin
        data_folder = "$$d_prefix"share/qupzilla
        launcher_folder = "$$d_prefix"share/applications
        icon_folder = "$$d_prefix"share/pixmaps
        hicolor_folder = "$$d_prefix"share/icons/hicolor
    }

    DEFINES += USE_DATADIR=\\\"""$$data_folder/"\\\""

    target.path = $$binary_folder

    target1.files += $$PWD/bin/locale
    target1.files += $$PWD/bin/themes
    target1.path = $$data_folder

    target2.files = $$PWD/linux/applications/qupzilla.desktop
    target2.path = $$launcher_folder

    target3.files = $$PWD/linux/pixmaps/qupzilla.png
    target3.path = $$icon_folder

    ico16.files = $$PWD/linux/hicolor/16x16/apps/qupzilla.png
    ico16.path = $$hicolor_folder/16x16/apps

    ico32.files = $$PWD/linux/hicolor/32x32/apps/qupzilla.png
    ico32.path = $$hicolor_folder/32x32/apps

    ico48.files = $$PWD/linux/hicolor/48x48/apps/qupzilla.png
    ico48.path = $$hicolor_folder/48x48/apps

    ico64.files = $$PWD/linux/hicolor/64x64/apps/qupzilla.png
    ico64.path = $$hicolor_folder/64x64/apps

    ico128.files = $$PWD/linux/hicolor/128x128/apps/qupzilla.png
    ico128.path = $$hicolor_folder/128x128/apps

    ico256.files = $$PWD/linux/hicolor/256x256/apps/qupzilla.png
    ico256.path = $$hicolor_folder/256x256/apps

    INSTALLS += target target1 target2 target3
    INSTALLS += ico16 ico32 ico48 ico64 ico128 ico256

    #Git revision
    rev = $$system(sh $$PWD/scripts/getrevision.sh)
    !equals(rev, ""): DEFINES += GIT_REVISION=\\\"""$$rev"\\\""
}